mirror of
https://github.com/systemd/systemd
synced 2025-10-05 16:03:15 +02:00
7d247d3cb8
[1] says: > Since 0.60.0 the name argument is optional and defaults to the basename of > the first output We specify >= 0.62 as the supported version, so drop the duplicate name in all cases where it is the same as outputs[0], i.e. almost all cases. [1] https://mesonbuild.com/Reference-manual_functions.html#custom_target
64 lines
2.5 KiB
Meson
64 lines
2.5 KiB
Meson
# SPDX-License-Identifier: LGPL-2.1-or-later
|
|
|
|
bashcompletiondir = get_option('bashcompletiondir')
|
|
if bashcompletiondir == ''
|
|
bash_completion = dependency('bash-completion', required : false)
|
|
if bash_completion.found()
|
|
bashcompletiondir = bash_completion.get_variable(pkgconfig : 'completionsdir')
|
|
else
|
|
bashcompletiondir = datadir / 'bash-completion/completions'
|
|
endif
|
|
endif
|
|
|
|
custom_target(
|
|
input : 'systemctl.in',
|
|
output : 'systemctl',
|
|
command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
|
|
install : bashcompletiondir != 'no',
|
|
install_dir : bashcompletiondir)
|
|
|
|
items = [['busctl', ''],
|
|
['journalctl', ''],
|
|
['systemd-analyze', ''],
|
|
['systemd-cat', ''],
|
|
['systemd-cgls', ''],
|
|
['systemd-cgtop', ''],
|
|
['systemd-creds', ''],
|
|
['systemd-delta', ''],
|
|
['systemd-detect-virt', ''],
|
|
['systemd-id128', ''],
|
|
['systemd-nspawn', 'ENABLE_NSPAWN'],
|
|
['systemd-path', ''],
|
|
['systemd-run', ''],
|
|
['systemd-vpick', ''],
|
|
['udevadm', ''],
|
|
['bootctl', ''],
|
|
['run0', ''],
|
|
['coredumpctl', 'ENABLE_COREDUMP'],
|
|
['homectl', 'ENABLE_HOMED'],
|
|
['hostnamectl', 'ENABLE_HOSTNAMED'],
|
|
['importctl', 'ENABLE_IMPORTD'],
|
|
['kernel-install', 'ENABLE_KERNEL_INSTALL'],
|
|
['localectl', 'ENABLE_LOCALED'],
|
|
['loginctl', 'ENABLE_LOGIND'],
|
|
['machinectl', 'ENABLE_MACHINED'],
|
|
['networkctl', 'ENABLE_NETWORKD'],
|
|
['oomctl', 'ENABLE_OOMD'],
|
|
['portablectl', 'ENABLE_PORTABLED'],
|
|
['resolvectl', 'ENABLE_RESOLVE'],
|
|
['systemd-cryptenroll', 'HAVE_LIBCRYPTSETUP'],
|
|
['systemd-confext', 'ENABLE_SYSEXT'],
|
|
['systemd-dissect', 'HAVE_BLKID'],
|
|
['systemd-resolve', 'ENABLE_RESOLVE'],
|
|
['systemd-sysext', 'ENABLE_SYSEXT'],
|
|
['systemd-vmspawn', 'ENABLE_VMSPAWN'],
|
|
['timedatectl', 'ENABLE_TIMEDATED'],
|
|
['userdbctl', 'ENABLE_USERDB']]
|
|
|
|
foreach item : items
|
|
if bashcompletiondir != 'no' and (item[1] == '' or conf.get(item[1]) == 1)
|
|
install_data(item[0],
|
|
install_dir : bashcompletiondir)
|
|
endif
|
|
endforeach
|